1

Awk 命令的多种用法，你知道几个？

 1 year ago
source link: https://os.51cto.com/article/710711.html
Go to the source link to view the article. You can view the picture content, updated content and better typesetting reading experience. If the link is broken, please click the button below to view the snapshot at that time.

Awk 命令的多种用法，你知道几个？-51CTO.COM

Awk 命令的多种用法，你知道几个？
作者：逄增宝 2022-06-04 08:29:27
在本文中，我们将看看这个简单的用法以及 awk 可以为你做的其他事情，并通过足够的示例向您展示该命令比想象的要灵活得多。

awk 命令提供的不仅仅是从输入字符串中选择字段，还包括提取数据列、打印简单文本、评估内容——甚至进行数学运算。

如果只在需要从文本行中选择特定字段时才使用 awk，你可能会错过该命令可以提供的许多其他用处。在本文中，我们将看看这个简单的用法以及 awk 可以为你做的其他事情，并通过足够的示例向您展示该命令比想象的要灵活得多。

提取数据列

awk 提供的最简单的用法是从文件或通过管道传输到它的数据中选择特定字段。默认使用空格作为字段分隔符：

[root@localhost ~]# echo one two three four five | awk '{print $4}'
four
[root@localhost ~]# who | awk '{print $1}'
root
root

在上面显示的命令中，awk 仅从提供的数据中提取第四个字段和第一个字段。

awk 还可以通过在 awk 命令后添加文件名来从文件中提取文本。

[root@localhost ~]# awk -F ':' '{print "user: "$1,"home: "$6,"shell: "$NF}' /etc/passwd
图片

在这种情况下，awk 使用-F ':'选项指定 冒号 作为分隔符。选出了文本中的第一列、第六列和最后一列。

命令中的 $NF​ 选择最后一个字段。这是因为 NF 表示一行中的字段数，而$NF 表示最后一个字段的值。

字段可以按你认为有用的任何顺序打印。在此示例中，我们正在重新排列 date 命令输出中的字段。

[root@localhost ~]# date | awk '{print "Date:",$6,$2,$3}'
Date: 2021 Sep 26

图片

如果你希望输出由其他符号来做分隔符，你可以使用 OFS（输出字段分隔符）指定输出分隔符，如下所示：

[root@localhost ~]# date | awk '{OFS="-"; print $6,$2,$3}'
2021-Sep-26

图片

还可以使用 awk 评估字段。例如，如果只想在 /etc/passwd 文件中列出UID大于1000的用户信息：

[root@localhost ~]# awk -F ':' '$3 >= 1000' /etc/passwd
nobody:x:65534:65534:Kernel Overflow User:/:/sbin/nologin
user01:x:1000:1000::/home/user01:/bin/bash
test01:x:1001:1001::/home/test01:/bin/bash
natasha:x:1002:1002::/home/natasha:/bin/bash
图片

如果要为列表添加标题，可以添加 BEGIN 子句，如果标题想要多行，可以使用\n换行符：

[root@localhost ~]# awk -F ':' 'BEGIN {print "user accounts\n=============="} $3 >= 1000' /etc/passwd
user accounts
==============
nobody:x:65534:65534:Kernel Overflow User:/:/sbin/nologin
user01:x:1000:1000::/home/user01:/bin/bash
test01:x:1001:1001::/home/test01:/bin/bash
natasha:x:1002:1002::/home/natasha:/bin/bash
图片

用awk做数学计算

awk 提供了算数能力，可以计算平方根、对数、切线等。

[root@localhost ~]# awk 'BEGIN {print sqrt(2021)}'
44.9555
[root@localhost ~]# awk 'BEGIN {print log(2019)}'
7.61036
图片

编写 awk 脚本

还可以使用 awk 编写独立脚本。这是一个模仿前面提供的示例之一的示例，但也计算了系统上拥有帐户的用户数。

[root@localhost ~]# vim list_users
#!/usr/bin/awk -f
# This line is a comment

BEGIN {
    printf "%s\n","User accounts:"
    print "=============="
    FS=":"
    n=0
}

# Now we'll run through the data
{
    if ($3 >= 1000) {
        print $1
        n ++
    }
}

END {
    print "=============="
    print n " accounts"
}
图片

请注意，仅在脚本启动时运行的 BEGIN 部分，提供标题、指示字段分隔符并设置从 0 开始的计数器。该脚本还包括一个 END 部分，该部分仅在脚本最后运行。

[root@localhost ~]# ./list_users /etc/passwd
User accounts:
==============
nobody
systemd-coredump
systemd-resolve
polkitd
sssd
chrony
unbound
user01
test01
natasha
==============
10 accounts
图片

计算文件中的行数

要使用 awk 打印文件中的行数，请执行以下操作：

[root@localhost ~]# awk 'END {print NR}' /etc/passwd
26
图片

命令中包含 END 意味着在处理行之后提供输出。NR（记录数）表示文件中的行数。

获取最常使用的命令

还可以将 awk 与许多其他命令一起使用，以查看在当前历史文件里面你最常使用的命令。

[root@localhost ~]# history | awk '{print $2}'|sort|uniq -c|sort -nr|head -5
     58 lvs
     48 ll
     31 vim
     29 vgs
     29 df
图片

​

图片

​


report

Recommend

About Joyk


Aggregate valuable and interesting links.
Joyk means Joy of geeK