前排提醒：阅读此文章并充分尝试 ModVB 的新语法需要较长的时间。对于程序员而言，如果你工作时不用 VB，则最好避免在上班时间看，以免被领导认为你在长时间摸鱼。

什么是 ModVB

ModVB 是一个免费和独立的 VB.NET “mod”，装一个 VSIX 和对应的 NuGet 包就能用新功能。

其中 mod 的意思包含：修改版（modified），现代（modern），以及 取模运算（modulo） (VB + ModVB) Mod VB = ModVB。

关于 ModVB 的作者

Anthony D. Green 在微软的托管编程语言团队有八年工作经验。大多时候是 Roslyn 编译器团队的项目群 / 项目集经理（Program Manager）。他从 13 岁起从 VB4 开始编程，在发布 ModVB 的第一个公测版本时 37 岁。

注：编写此文章时，Visual Studio 2022 版本为 17.3.2，插件版本为 0.0.1.0。示例中使用的操作系统是 Windows 10 x64 专业版 21H2，简体中文。

创建 Visual Studio 2022 的独立环境

此步骤用于隔离装了 ModVB 的环境和没装的环境，以便插件的分别管理。

• 启动 Visual Studio 2022 开发人员命令提示符
• 执行命令 devenv /rootSuffix ModVB
• 建议为 ModVB 创建一个快捷方式，例如

"C:\Program Files\Microsoft Visual Studio\2022\Community\Common7\IDE\devenv.exe" /rootSuffix ModVB

添加 ModVB 的 MyGet VSIX 源

从菜单上打开 工具→选项，左侧找到 环境→扩展

添加其他扩展库：

• 名称: ModVB
• 链接: https://www.myget.org/F/modvb/vsix/

点击应用（Apply）

添加 ModVB 的 NuGet 源

还是在选项对话框里。左侧找到NuGet包管理器→程序包源

在右边添加新的包源并且确保它已经打勾

• 名称: ModVB
• 源: https://www.myget.org/F/modvb/api/v3/index.json

点更新，然后确定。

下载和安装 ModVB 语言服务拓展

• 从菜单选择 扩展→管理扩展
• 在左侧选择 联机→ModVB
• 下载并安装 “ModVB Language Services (Built with Roslyn)”
• 重启 Visual Studio 完成拓展的安装

如何使用ModVB

注：由于代码高亮不完全支持这种修改过的 VB，对于未提及运行结果的代码，使用截图表示。仅对于代码高亮没问题的代码和带有执行结果的代码使用文本表示。

如何：启用ModVB编译器

• 新建一个 VB 项目，这里以 .NET 6.0 控制台应用为例。
• 在项目的引用上右键，选择管理 NuGet 包
• 右上方的下拉框里面，包源选择 ModVB
• 左边勾选包含预发布版
• 安装 “ModVB.Compilers.Toolset”。这个包是 ModVB 编译器。

如果下载速度慢，请自备对MyGet有效的加速器，或者找已经下载了并且你相信的人分享。

第一批功能：JSON 常量和模式匹配

选择JSON变量的类型

安装对应的 NuGet 包

使用 JSON 相关语法之前首先需要选择 JSON 常量使用哪些库。目前可选的有 Newtonsoft.Json 和 System.Text.Json。

如果选择 Newtonsoft.Json，则需要安装

如果选择 System.Text.Json，则需要安装

默认情况下，JSON 常量和模式匹配使用 Newtonsoft.Json 定义的类型。如果选择它之外的库，则需要定义编译常量来更改默认类型。

指定自动推断的 JSON 类型

假设有个项目，上述两种库都安装了。默认情况下，Json 对象是  Newtonsoft.Json.Linq.JObject。

如果想要默认用 System.Text.Json，需要在项目文件中定义编译常量。

<PropertyGroup>
  <DefineConstants>DEFAULT_JSON_OBJECT_TYPE = "System.Text.Json.Nodes.JsonObject",DEFAULT_JSON_ARRAY_TYPE = "System.Text.Json.Nodes.JsonArray"</DefineConstants>
</PropertyGroup>

效果如下图所示

按JSON变量的类型构造

那么，如果一个项目里想同时使用两种JSON类型呢？也是能做到的。只不过你需要写上JSON变量的类型，而不是让编译器自动推断类型。

JSON 常量

就像变量可以用 XML 常量初始化一样，ModVB 支持用 JSON 常量初始化变量，并且用法与 XML 常量有一定的相似性。

此章节的示例使用 Newtonsoft.Json 作为默认 JSON 类型。

以 NuGet 工具版本查询结果的片段为例。请求 https://dist.nuget.org/tools.json 能够得到类似于这样的 JSON并存储在变量中：

假如你打算生成类似的 JSON，可以把别的变量直接写进去换掉JSON的值。

有更多的版本需要显示也是没问题的，可以用 LINQ 表达式做个 JSON 对象数组出来，然后放到总的 JSON 里面。具体做法可参照下面的示例。

下列代码展示如何用 LINQ 结合 JSON 常量语法拼一个新的 JSON 出来。

ModVB

Module Program

    Sub Main()
        Dim latestVersion = "6.3.0"
        Dim stableVersions = {
            (ver:="6.2.1", uploaded:="2022-06-14T17:00:00.0000000Z"),
            (ver:="6.2.0", uploaded:="2022-05-10T13:00:00.0000000Z"),
            (ver:="6.1.0", uploaded:="2022-02-15T13:00:00.0000000Z")
        }

        Dim nugetVersions = {
  "nuget.exe": [
    {
      "version": latestVersion,
      "url": $"https://dist.nuget.org/win-x86-commandline/v{latestVersion}/nuget.exe",
      "stage": "Released",
      "uploaded": "2022-08-09T13:00:00.0000000Z"
    },
    From verInfo In stableVersions
    Select {
      "version": verInfo.ver,
      "url": $"https://dist.nuget.org/win-x86-commandline/v{verInfo.ver}/nuget.exe",
      "stage": "ReleasedAndBlessed",
      "uploaded": verInfo.uploaded
    }
  ]
}

        Console.WriteLine(nugetVersions)
    End Sub
End Module

这段代码的运行结果是：

JSON

{
  "nuget.exe": [
    {
      "version": "6.3.0",
      "url": "https://dist.nuget.org/win-x86-commandline/v6.3.0/nuget.exe",
      "stage": "Released",
      "uploaded": "2022-08-09T13:00:00.0000000Z"
    },
    {
      "version": "6.2.1",
      "url": "https://dist.nuget.org/win-x86-commandline/v6.2.1/nuget.exe",
      "stage": "ReleasedAndBlessed",
      "uploaded": "2022-06-14T17:00:00.0000000Z"
    },
    {
      "version": "6.2.0",
      "url": "https://dist.nuget.org/win-x86-commandline/v6.2.0/nuget.exe",
      "stage": "ReleasedAndBlessed",
      "uploaded": "2022-05-10T13:00:00.0000000Z"
    },
    {
      "version": "6.1.0",
      "url": "https://dist.nuget.org/win-x86-commandline/v6.1.0/nuget.exe",
      "stage": "ReleasedAndBlessed",
      "uploaded": "2022-02-15T13:00:00.0000000Z"
    }
  ]
}

上面的例子如果你觉得 nugetVersions 的变量声明太长了，你可以提取变量出来。JSON 常量支持扁平化操作，能够用来将多个 JSON 对象合并成一个，而不导致对象层次加深。

下面的代码将第一个版本信息中的两个属性提取了变量出来，并且剩余版本信息提取出了另一个变量。程序的执行结果不变。

ModVB

Module Program

    Sub Main()
        Dim latestVersion = "6.3.0"

        Dim stableVersions = {
            (ver:="6.2.1", uploaded:="2022-06-14T17:00:00.0000000Z"),
            (ver:="6.2.0", uploaded:="2022-05-10T13:00:00.0000000Z"),
            (ver:="6.1.0", uploaded:="2022-02-15T13:00:00.0000000Z")
        }

        Dim stable = From verInfo In stableVersions
                     Select {
      "version": verInfo.ver,
      "url": $"https://dist.nuget.org/win-x86-commandline/v{verInfo.ver}/nuget.exe",
      "stage": "ReleasedAndBlessed",
      "uploaded": verInfo.uploaded
    }

        Dim releasedStage = {
            "stage": "Released",
            "uploaded": "2022-08-09T13:00:00.0000000Z"
        }

        Dim nugetVersions = {
  "nuget.exe": [
    {
      "version": latestVersion,
      "url": $"https://dist.nuget.org/win-x86-commandline/v{latestVersion}/nuget.exe",
      {releasedStage}
    },
    stable
  ]
}

        Console.WriteLine(nugetVersions)
    End Sub
End Module

JSON 模式匹配

JSON模式匹配能在判断JSON的结构和内容的同时将所需的信息提取成变量。

以 JSON 常量例子中的 JSON 为例。假设你需要取得所有 stage 是 ReleasedAndBlessed 的 nuget.exe 版本以及其它信息，可以用下面的代码：

ModVB

Console.WriteLine("所有已发布的稳定版：")

Select Case ShapeOf nugetVersions
    Case {"nuget.exe": nodes}
        For Each node In nodes
            Select Case ShapeOf node
                Case {
                  "version": ver As Version,
                  "url": url As String,
                  "stage": "ReleasedAndBlessed",
                  "uploaded": relaseDate As Date
                }

                    Console.WriteLine($"{ver} 发布于 {relaseDate:F}，下载地址是 {url}")
            End Select
        Next

End Select

代码产生以下输出

控制台

所有已发布的稳定版：
6.2.1 发布于 2022年6月15日 1:00:00，下载地址是 https://dist.nuget.org/win-x86-commandline/v6.2.1/nuget.exe
6.2.0 发布于 2022年5月10日 21:00:00，下载地址是 https://dist.nuget.org/win-x86-commandline/v6.2.0/nuget.exe
6.1.0 发布于 2022年2月15日 21:00:00，下载地址是 https://dist.nuget.org/win-x86-commandline/v6.1.0/nuget.exe

Select Case ShapeOf 语句

Select Case ShapeOf 是模式匹配专用的 Select Case。它会改变Select Case内Case的含义，让它进行模式匹配，而不会与常规的 Select Case 语法产生冲突。

匹配 JSON 对象

匹配 JSON 对象需要用一对大括号包含 JSON 匹配模式，以下图为例解释。

• 匹配的顺序是从上到下，在行内从左到右。图中的属性1先匹配，属性2后匹配。
• 想要排除一个属性，可以匹配一个属性值是空。图中要求属性3必须为空。这样JSON没写属性3或者属性3写了是空才能匹配上。
• 如果冒号左边写问号，那么属性为空的时候仍然会匹配上。图中的属性4是可以为空的。包括这个属性没写，或者属性值写了是空。
• 如果 JSON 中有别的属性，并且大括号里面写了属性的匹配规则，那么其余的属性不影响匹配结果。
• 如果大括号里面也可以什么都不写，这个时候就只能匹配空的 JSON 对象。

匹配 JSON 数组

匹配 JSON 数组需要用一对中括号包含 JSON 匹配模式，以下图为例解释。

• 上图的意思是，按顺序从头开始匹配数组元素，它至少有指定的这些元素："元素1", "元素2", 345, true, false, null 。如果数组比预期的长，匹配仍然能够成功。
• 如果中括号里面什么也不写，则只能匹配空数组。

匹配 JSON 常量

任何 VB 常量表达式在这里都能使用。包括 Date, Decimal, Nothing。JSON 的常量（true, false, null）也能用。

按类型匹配并定义变量

• 如果值不为空，而且可转换为指定的类型，则匹配。
• 转换考虑了 TryCast, VB 内置的转换规则 以及 TryParse 之类的其它转换方式。
• 图中属性1会按字符串解析 JSON 内容并且尝试 TryParse。
• 图中属性2会按字符串解析 JSON。
• 图中属性3会原样返回 JSON 的值，前提是属性3不是空。

用问号表示可选

基本上每个模式匹配表达式最后都可以写一个问号，让表达式也能匹配空。这里认为属性未定义和值为空是相同的情况。下图是一些例子。

匹配一个可以为空的对象

匹配一个可以为空的值

属性1可以为空，属性2匹配一个属性并定义变量，属性值可以为空

当属性值为空时，定义的变量具备它的默认值。

运行时拓展和 API 兼容性

JSON 常量和模式匹配是基于模式的，类似于 LINQ 和 For Each 循环。它并不会绑在特定的库和类型上。这些功能在分析或编译代码时从特定的命名空间查找符合条件的类型，使用其中的成员。你甚至可以只装包含 ModVB 编译器的包，具体的模式匹配拓展包由你自己编写。通过反编译你的使用 JSON 常量和模式匹配的项目，你可以了解到如何编写 JSON 常量拓展包和模式匹配拓展包。

ModVB 作者写的两篇介绍：

此文章使用 CC BY-SA 4.0 协议，示例代码使用 MIT 协议。

此文章目前计划在 博客园，GitHub，哔哩哔哩，百度贴吧 使用用户名为 Nukepayload2 的账号发布。如果文章在别的地方出现，或者用户名不是 Nukepayload2，则属于被转载。